home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib14.dsk / TYPING HELPER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  62 lines
  1. 10  REM  **********************
  2. 20  REM  *    TYPING HELPER   *
  3. 30  REM  *   BY R. M. SMYTHE  *
  4. 40  REM  * COPYRIGHT (C) 1983 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * LINCOLN, MA. 01773 *
  7. 70  REM  **********************
  8. 80  GOTO 180
  9. 90 ::
  10. 100 : REM  PICK RANDOM WORD
  11. 110 :
  12. 120 X =  INT( RND(1) *A +B)
  13. 130 WR$ = WD$(X)
  14. 140  RETURN 
  15. 150 :
  16. 160 : REM  *** MAIN PROGRAM ***
  17. 170 :
  18. 180  GOSUB 470: REM  READ DATA
  19. 190  HOME : PRINT "CHOOSE FROM
  20. 200  VTAB 4: PRINT "2 LETTER 'WORDS'       ... TYPE A"
  21. 210  PRINT "3 LETTER 'WORDS'       ... TYPE B"
  22. 220  PRINT "REAL COMPUTER WORDS    ... TYPE C"
  23. 230  PRINT "TWO WORD PHRASES       ... TYPE D"
  24. 240 : VTAB 15: CALL  -868: INPUT "CHOICE ";A$
  25. 250  IF A$ < >"A"  AND A$ < >"B"  AND A$ < >"C"  AND A$ < >"D"  THEN 240
  26. 260  REM  SET CONSTRAINTS ON RANDOM NUMBER SELECTION
  27. 270 C =  ASC(A$) -64
  28. 280 A = A(C):B = 1: FOR I = 0 TO C -1:B = B +A(I): NEXT 
  29. 290  HOME :RT = 0
  30. 300  FOR QU = 1 TO 10
  31. 310  GOSUB 120
  32. 320  HOME 
  33. 330  VTAB (10): PRINT  TAB( 10)WR$
  34. 340  PRINT : HTAB 8: INPUT "> ";A$
  35. 350  IF A$ = WR$  THEN RT = RT +1
  36. 360  PRINT 
  37. 370  NEXT QU
  38. 380  FOR I = 1 TO 1000: NEXT 
  39. 390  HOME 
  40. 400  PRINT "YOU SCORED ";RT;" OUT OF 10"
  41. 410  VTAB 5: INPUT "MORE TYPING DRILL (Y/N) ? ";A$: IF A$ = "N"  THEN  END 
  42. 420  IF A$ < >"Y"  THEN 390
  43. 430  GOTO 190
  44. 440 :
  45. 450 : REM  READ WORDS INTO ARRAY
  46. 460 :
  47. 470  DIM WD$(100)
  48. 480 A(0) = 0
  49. 490 A(1) = 26: REM  26 TWO LETTER WORDS
  50. 500  DATA  CA,ON,TH,GO,LO,AD,SA,NO,GH,IN,HT,PR,QU,SO,OU,BE,DR,NG,OG,BL,ER,WA,WE,ST,ER
  51. 510  DATA  UP
  52. 520 A(2) = 16: REM  16 THREE LETTER WORDS
  53. 530  DATA  CAT,ING,THE,ONE,NOT,LOG,ATA,SAV,LOA,GOT
  54. 540  DATA  SOU,NOR,WES,EST,EAS,AST
  55. 550 A(3) = 30: REM  30 REAL WORDS
  56. 560  DATA  CATALOG,LOAD,SAVE,GO,NORTH,SOUTH,EAST,WEST,DRINK,WATER,TAKE,LEAVE,CLIMB,TREE,HOLE,DOWN,UP
  57. 570  DATA  RUN,AXE,LOAD,CATALOG,RUN,SAVE,LOCK,UNLOCK,DELETE,LOAD,CATALOG,RUN,SAVE
  58. 580 A(4) = 14: REM  14 PHRASES
  59. 590  DATA  GO NORTH, GO SOUTH, GO EAST, GO WEST, GO UP, GO DOWN, GO HOLE, CHOP TREE, TAKE AXE,LEAVE AXE, OPEN DOOR, TAKE LAMP,TAKE KEYS
  60. 600  DATA  LIGHT LAMP
  61. 610  FOR I = 1 TO 86: READ WD$(I): NEXT 
  62. 620  RETURN